#
# $Id: riverwarebase.pro,v 1.18 2011/06/27 17:59:07 nwilson Exp $
#

QT += network
QT += qt3support
QT += xml

CONFIG += qt debug_and_release exceptions rtti stl

# add the following to *Generated.pro with FORMS3 macros:
#CONFIG += uic3

QMAKE_UIC3 = Qt482-uic3.pl
#QMAKE_MOC  = moc.pl

DEFINES += IL_STD
DEFINES -= UNICODE
DEFINES += _WIN32
DEFINES += CW_PRESTOPLOT
CONFIG(debug, debug|release) {DEFINES += CWDEBUG}

# Uncomment for a purify or quantify build (disables Flexlm).
# After uncommenting or commenting:
#     - run qmakeRational.pl from Makefiles directory.
#     - recompile cwFlexlm.cpp in Halibut project.
#     - relink.
# When uncommented a release build will fail with undefined Flexlm
# symbols.
#RATIONAL_BUILD = 1

FLEXLM_DIR = C:/RiverWare/tools/flexlm

!exists($$FLEXLM_DIR) {
  DEFINES += NO_FLEXLM
}

# Inline function expansion
QMAKE_CXXFLAGS_DEBUG += /Ob0
QMAKE_CXXFLAGS_RELEASE += /Ob1

# Buffer Security Check
QMAKE_CXXFLAGS_DEBUG += /GS

# Optimize Code
QMAKE_CXXFLAGS_DEBUG += /Od
QMAKE_CXXFLAGS_RELEASE += /Og
QMAKE_CXXFLAGS_RELEASE += /Ot

# Eliminate Duplicate Strings
QMAKE_CXXFLAGS_RELEASE += /GF

# Enable Function-Level Linking
QMAKE_CXXFLAGS_RELEASE += /Gy

INCLUDEPATH += \
    ../Accounting \
    ../AccountingGUI \
    ../DbDmi \
    ../EngrObjs \
    ../GUI \
    ../Halibut \
    ../Opt \
    ../Optimize \
    ../Q3GUI \
    ../QtAccounting \
    ../QtDmi \
    ../QtRpl \
    ../QtRun \
    ../QtSCT \
    ../QtUtils \
    ../Rcl \
    ../Remote \
    ../Rpl \
    ../RplExpression \
    ../RwOracle \
    ../RwQt \
    ../Servers \
    ../Sim \
    ../Units \
    ../Utils \
    ../VCXX \
    C:/RiverWare/tools/ClientServer_Qt-46/include \
    C:/RiverWare/tools/RdfToExcel_Qt-46/include \
    C:/RiverWare/tools/Qwt-522_Qt-482/src \
    C:/RiverWare/tools/RepriseLM-90 \
    C:/RiverWare/tools/CPLEX-122/cplex/include \
    C:/RiverWare/tools/CPLEX-122/concert/include \
    C:/RiverWare/tools/Stubs/include \
    C:/RiverWare/tools/tcl-851/include \
    C:/RiverWare/tools/gdal-1.9.0/include \
    $$[QT_INSTALL_PREFIX]/src/3rdparty/zlib

# flexlm isn't available on 64-bit Windows
exists($$FLEXLM_DIR) {
  INCLUDEPATH += C:/RiverWare/tools/flexlm
}

UI_DIR = ./qt
MOC_DIR = ./qt

# Local Variables: ***
# mode: makefile ***
# End: ***